/* This Do-file creates a country-year data set using the 
   Correlates of War State System Membership data set.
   Specifically using:
   http://www.correlatesofwar.org/data-sets/state-system-membership/states2011/at_download/file
*/

version 12.1
clear all
set more off
insheet using "states2011.csv"

isid stateabb styear endyear

* Add variable labels:
label var stateabb "CoW State Abbreviation"
label var ccode    "CoW Country Code"
label var statenme "CoW State Name"
label var styear   "CoW membership start year"
label var stmonth  "CoW membership start month"
label var stday    "CoW membership start day"
label var endyear  "CoW membership end year"
label var endmonth "CoW membership end month"
label var endday   "CoW membership end day"
label var version  "CoW version number"

* Calculate number of observations to add for each state-membership observation:
gen years = endyear - styear + 1
* Create duplicate observations based on that calculation:
expand years
* Calculate the increments (roughly) from the start year:
bysort stateabb styear: egen seq_membership = seq()
* Generate a unique year for each country-year of membership:
gen year = styear + seq_membership - 1
label var year "Year"

* Check for a case of interrupted membership:
*browse styear year endyear if stateabb=="ALB"

* Drop tempory variables:
drop years seq_membership

isid ccode year
sort ccode year

/* The Correlates of War provides a country-year file based on their membership
   criteria at:
   http://www.correlatesofwar.org/data-sets/state-system-membership/system2011/at_download/file
   This file also has 14976 country-year observations, but contains fewer 
   variables than the country-year dataset we just created.
*/