/* Working with MIDs event data.
   Data downloaded on 25 January 2016 from 
   http://www.correlatesofwar.org/data-sets/MIDs/mid-level/at_download/file
*/

version 14.1
clear all
set more off
insheet using "MIDB_4.01.csv"

* Clean up missing value codes:
recode dispnum4 stday endday revtype2 fatality fatapre (-9=.)

* Identify unit of analysis:
isid dispnum3 ccode styear endyear
/* The unit of analysis for this data set is the
   dispute-country-period
*/

* Adding variable labels:
label var dispnum3 "Dispute number (Version 3)"
label var dispnum4 "Dispute number (Version 4)"
label var stabb    "State abbreviation of participant"
label var ccode    "Country code / state number of participant"
label var stday    "Start day of participation in dispute"
label var stmon    "Start month of participation in dispute"
label var styear   "Start year of participation in dispute"
label var endday   "End day of participation in dispute"
label var endmon   "End month of participation in dispute"
label var endyear  "End year of participation in dispute"
label var sidea    "Side A?"
label var revstate "Revisionist state?"
label var revtype1 "Revision type #1"
label var revtype2 "Revision type #2"
label var fatality "Fatality Level"
label var fatapre  "Precise Fatalities, if known"
label var hiact    "Highest action in dispute"
label var hostlev  "Hostility Level"
label var orig     "Originator of dispute?"
label var version  "Version number of data set"
/* Labels above come from "MID_v4.0_Codebook.pdf", pp. 5-6.
*/

* Label definitions:
#delimit;
label define noYes
	0 "No"
	1 "Yes"
;
label define RevType
	0 "Not applicable"
	1 "Territory"
	2 "Policy"
	3 "Regime/government"
	4 "Other"
;
label define Fatality
	0 "None"
	1 "1-25 deaths"
	2 "26-100 deaths"
	3 "101-250 deaths" 
	4 "251-500 deaths" 
	5 "501-999 deaths" 
	6 "> 999 deaths"
;
label define HiAct
    0  "No militarized action [1]"
    1  "Threat to use force [2]"
    2  "Threat to blockade [2]"
    3  "Threat to occupy territory [2]"
    4  "Threat to declare war [2]"
    5  "Threat to use CBR weapons [2]"
    6  "Threat to join war"
    7  "Show of force [3]"
    8  "Alert [3]"
    9  "Nuclear alert [3]"
    10 "Mobilization [3]"
    11 "Fortify border [3]"
    12 "Border violation [3]"
    13 "Blockade [4]"
    14 "Occupation of territory [4]"
    15 "Seizure [4]"
    16 "Attack [4]"
    17 "Clash [4]"
    18 "Declaration of war [4]"
    19 "Use of CBR weapons [4]"
    20 "Begin interstate war [5]"
    21 "Join interstate war [5]"
;
label define HostLev
    1 "No militarized action"
    2 "Threat to use force"
    3 "Display of force"
    4 "Use of force"
    5 "War"
;
#delimit cr
/* Label definitions above are from "MID_v4.0_Codebook.pdf", pp. 5-6.
*/

* Attaching label definitions to variables:
label values sidea revstate orig noYes
label values revtype1 revtype2 RevType
label values fatality Fatality
label values hiact HiAct
label values hostlev HostLev