/* Script to Combine Sexual Violence in Armed Conflict (SVAC) and Butler & Jones SV Data */
* Created by: Jess Jones
* Created on: June 2014
* Updated on: February 9, 2016
* Stata Version 12.1 - runs in Stata 14.1 

clear all
set more off
insheet using "http://www.unm.edu/~ckbutler/sfsv/SVAC_Dataset.csv", clear
* replace all missing, non-string values:
mvdecode _all, mv(-99=.)

* Unit-of-analysis is conflict-actor-year. Need to keep only those conflict-years in which the State is actor (Type 1) and after 1998.
keep if actor_type==1 & year>1998

* Dropping interstate wars. Unclear on location of SV (all are "0" except one - Eritrea, 2000 = 1):
tab type  state_prev
drop if type==2 

* Five cases of SV against non-citizens remain. 
list actor year selection_nationality if selection_nationality!="-99"
drop if selection_nationality!="-99"

* How many states have multiple entries and of what type:
codebook gwnoloc  /* 58 states */
bysort gwnoloc: tab conflictid type  /* 20 states have multiple conflicts (type 3 or 4) */

* Collapse multiple instances of conflict into country-years, using maximum prevalence scores for a year.
collapse (first) actor conflictid (max) conflictyear interm postc state_prev ai_prev hrw_prev selection male ///
	child detainee refugee gang byproxy, by(gwnoloc year)

* clean new dataset
label variable gwnoloc "G&W country code"
label variable actor "country name"
label variable conflictid "UCDP conflict number"
label variable conflictyear "dummy incidicating active conflict"
label variable interm "dummy indicating interim conflict-year (1-4 years inactivity)"
label variable postc "first 5 years after conflict"
label variable state_prev "State Dept SV Prevalence (Ordinal: 0-3)"
label variable ai_prev "Amnesty SV Prevalence (ordinal: 0-3)"
label variable hrw_prev "HRW SV Prevalence (ordinal: 0-3)"
label variable selection "Non-random targeting (dummy)"
label variable male "Level of male SV (ordinal: 0-2)"
label variable child "Level of child SV (ordinal: 0-2)"
label variable detainee "Level of detainee SV (ordinal: 0-2)"
label variable refugee "Level of refugee SV (ordinal: 0-2)"
label variable gang "SV by multiple perpetrators (dummy)"
label variable byproxy "Use of force to compel SV (dummy)"

label define prevalence 0 "No SV" 1 "Some SV" 2 "Several/Many SV" 3 "Massive SV" 
label values state_prev prevalence
label values ai_prev prevalence
label values hrw_prev prevalence

rename gwnoloc gwno
sort gwno year 

merge 1:1 gwno year using "http://www.unm.edu/~ckbutler/sfsv/SVcodes_onset_1999-2011.dta"