/* DO-file created by Christopher K. Butler on January 5, 2016.
   Designed to help verify the CrescenziEnterline1999JPR results.
*/

clear
insheet using "Crescenzi-Enterline JPR 99 (comma delimited).txt", comma case

/* These variable labels are directly from 
   'Crescenzi-Enterline JPR 99 list of variables.txt'
*/
label var AllState "Number of states in the Global System"
label var Astate "Number of states in the African Regional System"
label var AsState "Number of states in the Asian Regional System"
label var Estate "Number of states in the European Regional System"
label var WHState "Number of states in the Western Hemisphere Regional System"
label var MEState "Number of states in the Middle East Regional System"
label var AllDD "Frequency of Democratic Regime Changes for the Global System"
label var ADD  "Frequency of Democratic Regime Changes for the African Regional System"
label var AsDD  "Frequency of Democratic Regime Changes for the Asian Regional System"
label var EDD  "Frequency of Democratic Regime Changes for the European Regional System"
label var WHDD  "Frequency of Democratic Regime Changes for the Western Hemisphere Regional System"
label var MEDD  "Frequency of Democratic Regime Changes for the Middle East Regional System"
label var AllPDem "Frequency of Democratic Regimes for Global System"
label var APDem  "Frequency of Democratic Regimes for African Regional System"
label var AsPDem  "Frequency of Democratic Regimes for Asian Regional System"
label var EPDem  "Frequency of Democratic Regimes for European Regional System"
label var WHPDem  "Frequency of Democratic Regimes for Western Hemisphere Regional System"
label var MePDem  "Frequency of Democratic Regimes for Global System"
label var AllWars  "Frequency of Wars for Global System"
label var Awars  "Frequency of Wars for African Regional System"
label var AsWars  "Frequency of Wars for Asian Regional System"
label var Ewars  "Frequency of Wars for European Regional System"
label var WHWars  "Frequency of Wars for Western Hemisphere Regional System"
label var MeWars  "Frequency of Wars for Middle East Regional System"

/* These variable labels were inferred from the article (figure 2 in particular)
   and the names and ranges of the variables.
*/
label var AllPDNorm "Proportion of Democracy, Global"
label var APDNorm "Proportion of Democracy, Africa"
label var AsPDNorm "Proportion of Democracy, Asia"
label var EPDNorm "Proportion of Democracy, Europe"
label var WHPDNorm "Proportion of Democracy, Western Hemisphere"
label var MePDNorm "Proportion of Democracy, Middle East"

/* Verifing Figure 2 as a series of separate scatter plots.
*/
graph drop _all
#delimit ;
scatter AllPDNorm Year, 
    msymbol(i) connect(l)
    xlabel(1820 1840 1860 1880 1900 1920 1940 1960 1980)
    ylabel(0 .1 .2 .3 .4 .5 .6)
    name(Fig2_Global)
;
scatter APDNorm Year, 
    msymbol(i) connect(l)
    xlabel(1820 1840 1860 1880 1900 1920 1940 1960 1980)
    ylabel(0 .2 .4 .6 .8 1)
    name(Fig2_Africa)
;
scatter EPDNorm Year, 
    msymbol(i) connect(l)
    xlabel(1820 1840 1860 1880 1900 1920 1940 1960 1980)
    ylabel(0 .2 .4 .6 .8 1)
    name(Fig2_Europe)
;
scatter MePDNorm Year, 
    msymbol(i) connect(l)
    xlabel(1820 1840 1860 1880 1900 1920 1940 1960 1980)
    ylabel(0 .05 .1 .15 .2 .25 .3)
    name(Fig2_MiddleEast)
;
scatter AsPDNorm Year, 
    msymbol(i) connect(l)
    xlabel(1820 1840 1860 1880 1900 1920 1940 1960 1980)
    ylabel(0 .1 .2 .3 .4 .5)
    name(Fig2_Asia)
;
scatter WHPDNorm Year, 
    msymbol(i) connect(l)
    xlabel(1820 1840 1860 1880 1900 1920 1940 1960 1980)
    ylabel(0 .2 .4 .6 .8 1)
    name(Fig2_WestHem)
;
#delimit cr
*exit
graph drop _all

*help var
*help tsset
tsset Year

/* Attempting to replicate findings for 
   different time periods, global sample.
*/
#delimit ;
eststo global1816_1875: var AllPDNorm  AllDDNorm AllWNorm 
    if Year<1876
    ,
    lags(1/4)
    small
;
eststo global1876_1935: var AllPDNorm  AllDDNorm AllWNorm 
    if Year>=1876 & Year<=1935
    ,
    lags(1/4)
    small
;
eststo global1936_1992: var AllPDNorm  AllDDNorm AllWNorm 
    if Year>1935
    ,
    lags(1/4)
    small
;
#delimit cr
/* The 'vargranger' command seems to be different from whatever 
   eViews was doing.
*/
*vargranger, est(global1816_1875)
*vargranger, est(global1876_1935)
*vargranger, est(global1936_1992)

irf create temp, set(temp.txt, replace) step(10)
irf graph irf, name(irf_global1936_1992)

estimates restore global1876_1935
irf create temp, set(temp.txt, replace) step(10)
irf graph irf, name(irf_global1876_1935)

estimates restore global1816_1875
irf create temp, set(temp.txt, replace) step(10)
irf graph irf, name(irf_global1816_1875)

/* While presented in a different order in their appendices
   (specifically Figures 8(a-c) and 9(a-c) in 'techappC.ppt'),
   Figures 8b and 8c are clearly replicated in their corresponding
   IRF graphs. This is more difficult to tell for the others as the
   original y-axis scales are stretched to make the IRF discernable.   
*/

exit
*Additional global verification.
scatter AllDDNorm Year, msymbol(i) c(l) name(Fig6a)
scatter AllWNorm Year, msymbol(i) c(l) name(Fig7a)

/* Ultimately, this is not a fully successful verification or replication.
   We are able to verify the global variables via time-series plots.
   We are only able to replicate the global VAR in the sense that we
   ran the same estimation with the appropriate number of lags. 
   It replicates (visually) in the IRF graphs that were not overly distorted,
   but it is more tenuous to say that we replicated the original 
   results and implications. 
   We also stopped short of doing the analysis at any of the regional levels.
   I did note that two of the regional *DDNorm variables are currently 
   string variables and would need to be cleaned up (due to a '#DIV/0!' coding).
   Also, the number of observations for the 1816-1875 period is 
   different between the original and the replication.

*/